Temperature sensors compared

The sensors

Values from the manufacturers' datasheets. The DHT22 protocol is not compatible with the DS18B20's 1-Wire.

Which one to choose

• Air, accurately: SHT4x: ±0.2 °C typical, plus humidity.
• Water, soil, outdoors: waterproof DS18B20 probe; several probes on the same wire, each with its own 64-bit code.
• Weather station: BME280 for pressure and humidity; for air temperature a separate sensor, away from the electronics, is better.
• Lowest cost, or ovens and 3D printers: NTC, with a good fixed resistor and a calibration.
• Simple analog: TMP36, which also works at 3.3 V; the LM35 needs at least 4 V and a negative supply for temperatures below zero.

NTC: two things to watch

The formula. The Beta equation is handy but approximate: with B = 3950, against the table of the Adafruit 4890 thermistor, it is off by about +0.5 °C at 0 °C and +2.2 °C at −40 °C (our own calculation). And “3950” thermistors from different brands do not share the same curve: Adafruit sells two 3950 thermistors with different tables. For wide ranges use your thermistor's table.
Self-heating. With a 10 kΩ + 10 kΩ divider at 5 V the thermistor dissipates 0.625 mW and warms up slightly. Adafruit suggests powering the divider from a pin only while reading.

Wiring: DS18B20 probe on the ESP32

Sketch: DS18B20

// DS18B20: reads all the probes connected to the same data wire (1-Wire) and prints the temperature of each one.
// Data wire with a 4.7 kohm resistor to VCC. Same sketch for Arduino UNO and ESP32.
// Libraries: OneWire and DallasTemperature.
#include <OneWire.h>
#include <DallasTemperature.h>

#ifdef ARDUINO_ARCH_ESP32
const int PIN_DATI = 4;
#else
const int PIN_DATI = 2;
#endif

OneWire filo(PIN_DATI);
DallasTemperature sonde(&filo);

void setup() {
  Serial.begin(115200);
  sonde.begin();
  Serial.print("Probes found: ");
  Serial.println(sonde.getDeviceCount());
}

void loop() {
  sonde.requestTemperatures();          // they all measure together; at 12 bits it takes up to 750 ms
  for (int i = 0; i < sonde.getDeviceCount(); i++) {
    float gradi = sonde.getTempCByIndex(i);
    Serial.print("Probe ");
    Serial.print(i);
    Serial.print(": ");
    if (gradi == DEVICE_DISCONNECTED_C) {
      Serial.println("not responding");
    } else {
      Serial.print(gradi, 2);
      Serial.println(" C");
    }
  }
  delay(2000);
}

You need the OneWire and DallasTemperature libraries. If you read −127 the probe is not responding; if you read exactly 85.00, that is the DS18B20's power-on value: the conversion did not happen. At 12 bits each conversion takes up to 750 ms; at 9 bits 94 ms are enough, with half-degree resolution.

Sketch: NTC

// 10 kohm NTC thermistor (B 3950) with the Beta equation, as in the Adafruit "Thermistor" guide.
// Divider: 10 kohm fixed resistor between + and the pin, NTC between the pin and GND.
// Same sketch for Arduino UNO and ESP32.
#include <Arduino.h>
#include <math.h>

const float R_FISSA = 10000.0;   // ohm (1% is better)
const float R_NOM = 10000.0;     // NTC resistance at 25 degrees
const float T_NOM = 298.15;      // 25 degrees in kelvin
const float BETA = 3950.0;       // from your thermistor's datasheet

#ifdef ARDUINO_ARCH_ESP32
const int PIN_NTC = 34;
const float VCC_MV = 3300.0;     // divider voltage: measure it on the 3V3 pin and write it here
#else
const int PIN_NTC = A0;
#endif

float resistenzaNtc() {
  float media = 0;
  for (int i = 0; i < 5; i++) {  // average of 5 readings, as in the Adafruit example
#ifdef ARDUINO_ARCH_ESP32
    media += analogReadMilliVolts(PIN_NTC);
#else
    media += analogRead(PIN_NTC);
#endif
    delay(10);
  }
  media /= 5;
#ifdef ARDUINO_ARCH_ESP32
  // the ESP32 ADC does not use the 3.3 V as its reference: we work in millivolts
  return R_FISSA * media / (VCC_MV - media);
#else
  // on the UNO the divider and the ADC use the same 5 V: the ratio is enough
  return R_FISSA / (1023.0 / media - 1.0);
#endif
}

void setup() {
  Serial.begin(115200);
}

void loop() {
  float rNtc = resistenzaNtc();
  // Beta equation: 1/T = 1/T_NOM + ln(R/R_NOM)/B
  float kelvin = 1.0 / (1.0 / T_NOM + log(rNtc / R_NOM) / BETA);
  Serial.print("R = ");
  Serial.print(rNtc, 0);
  Serial.print(" ohm   T = ");
  Serial.print(kelvin - 273.15, 1);
  Serial.println(" C");
  delay(1000);
}

10 kΩ fixed resistor between + and the pin, NTC between the pin and GND. On the UNO the ratio between reading and full scale is enough, because the divider and the converter use the same 5 V. Not on the ESP32: you read in millivolts and need the real voltage of the 3.3 V rail, which you have to measure. On the ESP32, below about 5 °C, the pin goes above the 2.45 V of the accurate range.

Common mistakes