The heartbeat on Arduino: an ECG with the AD8232

2How it works and how to wire it

This is a single-lead ECG: it measures the voltage between the right arm (RA) and the left arm (LA); the third electrode (RL, right leg) helps the AD8232 keep the noise down. The SparkFun board follows the Analog Devices “cardiac monitor” circuit: the signal is made 1100 times larger, and only frequencies between 0.5 and 40 Hz get through. OUTPUT swings around 1.65 V, which Arduino reads as about 340 (our calculation).

• 3.3v → 3.3V, never to 5V: the AD8232 works from 2 to 3.5 V and can take 3.6 V at most.
• LO+ → A1, LO− → A2: they go up to 3.3 V when LA (LO+) or RA (LO−) comes off. A digital pin on the UNO is only sure to see a “high” from 3 V up (ATmega328P datasheet), so we read them with analogRead: about 675 (our calculation) with the electrode off, almost 0 with the electrode on.
• SDN stays free (a resistor on the board keeps the chip on). Never connect it to a pin on the UNO: the UNO's 5 V is more than the chip can take.

3The sketch

// The heart's signal with the AD8232 and Arduino UNO. For learning only: this is NOT
// a medical device. Electrodes on the body only when everything runs on batteries.
#include <Arduino.h>

const bool HAS_LO = true;  // false for the DFRobot SEN0213 (LO+ and LO- not available)
const byte EVERY = 10;     // one line to the Plotter every 10 readings (IDE 1.8: use 1)
const int MARGIN = 100;    // how far the R peak must rise above the average (adjust it)

long sum;                  // moving average of the readings, multiplied by 64
unsigned long lastRead, lastBeat;
bool above = false;        // is the signal already above the threshold?
int bpm = 0, highest = 0;
byte counted = 0;

void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);       // the L LED blinks at every beat
  sum = analogRead(A0) * 64L;
  lastRead = micros();
}

void loop() {
  if (micros() - lastRead < 4000) return;        // one reading every 4 ms
  lastRead += 4000;
  int value = analogRead(A0);                    // OUTPUT of the module
  sum += value - sum / 64;                       // the average follows the baseline
  int threshold = sum / 64 + MARGIN;
  unsigned long now = millis();
  // LO+ (A1) and LO- (A2): about 675 if an electrode is off, almost 0 if it is on
  if (HAS_LO && (analogRead(A1) > 400 || analogRead(A2) > 400)) {
    value = threshold = bpm = 0;                 // on the Plotter: flat line at zero
  } else if (!above && value > threshold) {      // R peak: one beat
    above = true;
    unsigned long interval = now - lastBeat;
    if (interval > 300) {                        // under 0.3 s it is not a new beat
      if (interval < 2000) bpm = 60000UL / interval;
      lastBeat = now;
    }
  } else if (value < threshold) {
    above = false;
  }
  digitalWrite(LED_BUILTIN, now - lastBeat < 100);   // on for 0.1 s
  // the highest reading of each group goes to the Plotter, so the R peak is not lost
  if (counted == 0 || value > highest) highest = value;
  if (++counted < EVERY) return;
  counted = 0;
  Serial.print(F("ECG:"));         Serial.print(highest);
  Serial.print(F(",Threshold:"));  Serial.print(threshold);
  Serial.print(F(",BPM:"));        Serial.println(bpm);
}

Arduino reads OUTPUT 250 times a second: above the threshold (the average plus MARGIN) there is an R peak and the L LED lights up. The Plotter gets one line every ten readings because the one in IDE 2, as its source code shows, displays only the last 50 lines: two seconds. With the old IDE 1.8 (500 lines), set EVERY = 1.

4Where the electrodes go

SparkFun gives two placements: forearms and right thigh (A) or chest near the shoulders and right side above the hip (B); the closer they are to the heart, the better. On the SparkFun cable RA is black, LA blue, RL red: other cables differ, so check the labels.

5Watch the trace

Charger unplugged, sketch uploaded, electrodes on: open the Serial Plotter (Tools menu or the button at the top right) at 115200 baud.