The keypad: a lock with a secret code

1Get the parts ready

• a 3×4 membrane keypad (thin and adhesive, with seven pins at the end of its tail)
• a passive buzzer (guide no. 38), Arduino UNO, seven male-to-male jumper wires

2Connect the seven pins

With the keypad in front of you, count the pins from the left: the first four are the rows and go to pins 2, 3, 4, 5; the last three are the columns and go to pins 8, 9, 10. The buzzer goes between pin 12 and GND. No resistors: the library takes care of it.

3Read the keys

From the Library Manager install Keypad by Mark Stanley and Alexander Brevig.

// The 3x4 keypad: prints the key you press in the Serial Monitor.
#include <Arduino.h>
#include <Keypad.h>

const byte ROWS = 4, COLS = 3;
char keys[ROWS][COLS] = {        // how the keypad is laid out
  {'1', '2', '3'},
  {'4', '5', '6'},
  {'7', '8', '9'},
  {'*', '0', '#'}
};
byte rowPins[ROWS] = {2, 3, 4, 5};          // keypad pins 1-4 (with the ESP32: 13, 14, 27, 32)
byte colPins[COLS] = {8, 9, 10};            // keypad pins 5-7 (with the ESP32: 26, 25, 33)

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

void setup() {
  Serial.begin(115200);
}

void loop() {
  char key = keypad.getKey();   // NO_KEY if you have not pressed anything
  if (key != NO_KEY) {
    Serial.println(key);
  }
}

4The secret code

// The secret code: type the digits and press # to try it, * to clear. If it is right the small L light turns on.
#include <Arduino.h>
#include <Keypad.h>

const byte ROWS = 4, COLS = 3;
char keys[ROWS][COLS] = {
  {'1', '2', '3'},
  {'4', '5', '6'},
  {'7', '8', '9'},
  {'*', '0', '#'}
};
byte rowPins[ROWS] = {2, 3, 4, 5};          // with the ESP32: 13, 14, 27, 32
byte colPins[COLS] = {8, 9, 10};            // with the ESP32: 26, 25, 33
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

const String SECRET = "1234";    // change it to your own code
const int LED = 13;              // the small L light (with the ESP32: an LED on 23)
const int BUZZER = 12;           // with the ESP32 write 4
String typed = "";               // the digits pressed so far

void setup() {
  pinMode(LED, OUTPUT);
  Serial.begin(115200);
  Serial.println("Type the code and press #");
}

void loop() {
  char key = keypad.getKey();
  if (key == NO_KEY) return;             // nothing new: start the loop again

  tone(BUZZER, 2000, 30);                // a small click for each key
  if (key == '*') {                      // clear
    typed = "";
    Serial.println("Cleared");
  } else if (key == '#') {               // try the code
    if (typed == SECRET) {
      Serial.println("Right code!");
      digitalWrite(LED, HIGH);
      delay(3000);                       // open for 3 seconds
      digitalWrite(LED, LOW);
    } else {
      Serial.println("Wrong code");
      tone(BUZZER, 300, 600);            // a low, long sound
    }
    typed = "";
  } else {
    typed += key;                        // add the digit at the end
    Serial.print("*");                   // you only see an asterisk, like at the ATM
  }
}

5Challenge yourself

6And with the ESP32?

It works the same way: rows on GPIO 13, 14, 27, 32, columns on 26, 25, 33, buzzer on 4. We avoid GPIO 12, which the ESP32 reads at power-up to decide how to start.