A real voltage: the 12-bit MCP4725 DAC

2The module

• VIN and GND: power, 2.7 to 5.5 V for the chip. Adafruit recommends the same voltage as the board that controls it: the 10 kΩ pull-up resistors take SDA and SCL up to VIN itself. So with the ESP32, 3.3 V.
• SCL and SDA: the I²C bus (guide no. 22). The address is 0x62; it becomes 0x63 if you take A0 to VIN or close the “Addr” jumper on the back. This way two modules can share the same bus.
• VOUT: the output. The same signals, except VOUT, also go through the two STEMMA QT connectors.

3How much one step is worth

• At 5 V one step is 1.22 mV (datasheet table); at 3.3 V about 0.8 mV (our calculation).
• With 4095 the output gets to one step below VDD, not to VDD.
• Near the ends of the range the accuracy drops: Microchip measures linearity between codes 100 and 4000, and the zero error is not calibrated at the factory.

4Connect and measure

• Five straight wires: 3V3 → VIN, GND → GND, 22 → SCL, 21 → SDA, 35 → VOUT. Pin 35 is also A3, an analog input: this way the FireBeetle reads back the voltage it asked for.
• VIN to 3V3, never to VCC: VCC carries the roughly 5 V from USB, the pull-ups would bring SDA and SCL to 5 V as well, and the ESP32 pins cannot take that (guide no. 21).
• Multimeter on V⎓: black probe in the − hole and red probe in the + hole of the optional terminal block (they are GND and VOUT), or straight onto the GND and VOUT pins.

5Four voltages

// The MCP4725 DAC: four voltages, one every 4 seconds. Measure them with the
// multimeter between VOUT and GND; A3 reads them back. Library: Adafruit MCP4725.
#include <Arduino.h>
#include <Adafruit_MCP4725.h>

const byte ADDRESS = 0x62;      // Adafruit 935: 0x62 (0x63 with the jumper closed)
#ifdef ESP32
const float VDD = 3.3;          // FireBeetle 2 ESP32-E: module on 3V3
#else
const float VDD = 5.0;          // Arduino UNO: module on 5V
#endif
const int CODES[] = {0, 1024, 2048, 4095};   // from 0 to 4095: 12 bits

Adafruit_MCP4725 dac;

void setup() {
  Serial.begin(115200);
  if (!dac.begin(ADDRESS)) {
    Serial.println(F("MCP4725 not responding: check the wires and the address"));
    while (true) delay(1000);
  }
}

void loop() {
  for (int code : CODES) {
    dac.setVoltage(code, false);             // false: the EEPROM is left alone
    delay(50);
    Serial.print(F("code "));
    Serial.print(code);
    Serial.print(F("  about "));
    Serial.print(code * VDD / 4096, 2);      // the datasheet formula
    Serial.print(F(" V  A3: "));
#ifdef ESP32
    Serial.print(analogReadMilliVolts(A3));  // millivolts
    Serial.println(F(" mV"));
#else
    Serial.println(analogRead(A3));          // from 0 to 1023: about code / 4
#endif
    delay(4000);
  }
}

Install the Adafruit MCP4725 library. dac.begin(0x62) returns false if the chip does not answer; setVoltage(code, false) changes the output without touching the EEPROM. Open the Serial Monitor at 115200 baud: for each code you get the expected voltage and the one read on A3.

6A wave on the Plotter

// A wave from the MCP4725 DAC and what A3 reads back, both on the Serial Plotter.
#include <Arduino.h>
#include <Adafruit_MCP4725.h>

const byte ADDRESS = 0x62;      // Adafruit 935
const bool SINE = false;        // true: sine wave; false: triangle wave
const int POINTS = 32;          // points in each period

Adafruit_MCP4725 dac;
int point = 0;

void setup() {
  Serial.begin(115200);
  if (!dac.begin(ADDRESS)) {
    Serial.println(F("MCP4725 not responding: check the wires and the address"));
    while (true) delay(1000);
  }
}

void loop() {
  int code;
  if (SINE) {
    code = 2048 + 2047 * sin(TWO_PI * point / POINTS);
  } else {                                     // up for half a period, then down
    int half = POINTS / 2;
    int rise = point < half ? point : POINTS - point;
    code = rise * 4095L / half;
  }
  dac.setVoltage(code, false);
  delay(2);
#ifdef ESP32
  Serial.print(F("Sent_mV:"));
  Serial.print(code * 3300L / 4096);           // module on 3V3
  Serial.print(F(",A3_mV:"));
  Serial.println(analogReadMilliVolts(A3));
#else
  Serial.print(F("Sent:"));
  Serial.print(code / 4);                      // in A3 counts: 1023 = 5 V
  Serial.print(F(",A3:"));
  Serial.println(analogRead(A3));
#endif
  point = (point + 1) % POINTS;
  delay(40);
}

About every 40 milliseconds the DAC takes a step: 32 points to go up and down. Open the Serial Plotter at 115200 baud. With SINE = true the wave becomes a sine wave, centered on half the supply. The Plotter in IDE 2 shows the last 50 lines, a little more than one and a half waves.