Una tensione vera: il DAC MCP4725 a 12 bit

2Il modulo

• VIN e GND: alimentazione, da 2,7 a 5,5 V per il chip. Adafruit consiglia la stessa tensione della scheda che lo comanda: le resistenze di pull-up da 10 kΩ portano SDA e SCL proprio a VIN. Con l'ESP32 quindi 3,3 V.
• SCL e SDA: il bus I²C (guida n. 22). L'indirizzo è 0x62; diventa 0x63 portando A0 a VIN o chiudendo il ponticello «Addr» sul retro. Così sullo stesso bus ci stanno due moduli.
• VOUT: l'uscita. Gli stessi segnali, VOUT escluso, passano anche dai due connettori STEMMA QT.

3Quanto vale un passo

• A 5 V un passo vale 1,22 mV (tabella del datasheet); a 3,3 V circa 0,8 mV (calcolo nostro).
• Con 4095 l'uscita arriva a un passo sotto VDD, non a VDD.
• Vicino agli estremi la precisione cala: Microchip misura la linearità tra i codici 100 e 4000 e l'errore di zero non è tarato in fabbrica.

4Collega e misura

• Cinque fili dritti: 3V3 → VIN, GND → GND, 22 → SCL, 21 → SDA, 35 → VOUT. Il 35 è anche A3, un ingresso analogico: così la FireBeetle rilegge la tensione che ha chiesto.
• VIN al 3V3, mai al VCC: lì arrivano i circa 5 V dell'USB, le pull-up porterebbero a 5 V anche SDA e SCL, e i pin dell'ESP32 non li reggono (guida n. 21).
• Tester su V⎓: puntale nero nel foro − e rosso nel foro + del morsetto opzionale (sono GND e VOUT), oppure direttamente sui pin GND e VOUT.

5Quattro tensioni

// Il DAC MCP4725: quattro tensioni, una ogni 4 secondi. Misurale con il tester
// tra VOUT e GND; A3 le rilegge. Libreria: Adafruit MCP4725.
#include <Arduino.h>
#include <Adafruit_MCP4725.h>

const byte INDIRIZZO = 0x62;    // Adafruit 935: 0x62 (0x63 con il ponticello chiuso)
#ifdef ESP32
const float VDD = 3.3;          // FireBeetle 2 ESP32-E: modulo al 3V3
#else
const float VDD = 5.0;          // Arduino UNO: modulo al 5V
#endif
const int CODICI[] = {0, 1024, 2048, 4095};   // da 0 a 4095: 12 bit

Adafruit_MCP4725 dac;

void setup() {
  Serial.begin(115200);
  if (!dac.begin(INDIRIZZO)) {
    Serial.println(F("MCP4725 non risponde: controlla i fili e l'indirizzo"));
    while (true) delay(1000);
  }
}

void loop() {
  for (int codice : CODICI) {
    dac.setVoltage(codice, false);           // false: la EEPROM non si tocca
    delay(50);
    Serial.print(F("codice "));
    Serial.print(codice);
    Serial.print(F("  circa "));
    Serial.print(codice * VDD / 4096, 2);    // la formula del datasheet
    Serial.print(F(" V  A3: "));
#ifdef ESP32
    Serial.print(analogReadMilliVolts(A3));  // millivolt
    Serial.println(F(" mV"));
#else
    Serial.println(analogRead(A3));          // da 0 a 1023: circa codice / 4
#endif
    delay(4000);
  }
}

Installa la libreria Adafruit MCP4725. dac.begin(0x62) risponde false se il chip non si fa sentire; setVoltage(codice, false) cambia l'uscita senza toccare la EEPROM. Apri il Monitor seriale a 115200 baud: per ogni codice c'è la tensione attesa e quella letta da A3.

6Un'onda sul Plotter

// Un'onda dal DAC MCP4725 e quello che rilegge A3, insieme sul Plotter seriale.
#include <Arduino.h>
#include <Adafruit_MCP4725.h>

const byte INDIRIZZO = 0x62;    // Adafruit 935
const bool SENO = false;        // true: onda sinusoidale; false: triangolare
const int PUNTI = 32;           // punti in ogni periodo

Adafruit_MCP4725 dac;
int punto = 0;

void setup() {
  Serial.begin(115200);
  if (!dac.begin(INDIRIZZO)) {
    Serial.println(F("MCP4725 non risponde: controlla i fili e l'indirizzo"));
    while (true) delay(1000);
  }
}

void loop() {
  int codice;
  if (SENO) {
    codice = 2048 + 2047 * sin(TWO_PI * punto / PUNTI);
  } else {                                     // sale per metà periodo, poi scende
    int meta = PUNTI / 2;
    int salita = punto < meta ? punto : PUNTI - punto;
    codice = salita * 4095L / meta;
  }
  dac.setVoltage(codice, false);
  delay(2);
#ifdef ESP32
  Serial.print(F("Inviato_mV:"));
  Serial.print(codice * 3300L / 4096);         // modulo al 3V3
  Serial.print(F(",A3_mV:"));
  Serial.println(analogReadMilliVolts(A3));
#else
  Serial.print(F("Inviato:"));
  Serial.print(codice / 4);                    // in punti di A3: 1023 = 5 V
  Serial.print(F(",A3:"));
  Serial.println(analogRead(A3));
#endif
  punto = (punto + 1) % PUNTI;
  delay(40);
}

Ogni 40 millesimi di secondo circa il DAC fa un passo: 32 punti per salire e scendere. Apri il Plotter seriale a 115200 baud. Con SENO = true l'onda diventa una sinusoide, centrata su metà alimentazione. Il Plotter dell'IDE 2 mostra le ultime 50 righe, poco più di un'onda e mezza.