From bits to real values: converting sensor readings

Step 1: from the number to volts

The converter returns an integer. To get volts you multiply it by the value of one step, that is the full scale divided by the number of levels:

Step 2: from volts to the quantity

Complete example with the ADS1115

The capacitive soil sensor

Wiring with the ESP32 and the ADS1115

The sketch

// From bits to real values with the ADS1115:
//  A0 = capacitive soil moisture sensor (DFRobot SEN0193): two-point calibration, air and water
//  A1 = TMP36 analog temperature sensor: 10 mV per degree, 500 mV at 0 degrees
// Same sketch for Arduino UNO and ESP32. Library: Adafruit ADS1X15.
#include <Adafruit_ADS1X15.h>

Adafruit_ADS1115 ads;

// Calibration: write YOUR two readings in volts here (see the guide, step 2).
// These are the values from the DFRobot example (520 and 260 on Arduino UNO, that is 2.54 V and 1.27 V):
// every sensor is a little different, so measure yours.
const float V_AIR = 2.54;     // dry sensor, in the air
const float V_WATER = 1.27;   // sensor in a glass of water, not past the line

void setup() {
  Serial.begin(115200);
  if (!ads.begin(0x48)) {
    Serial.println("ADS1115 not found");
    while (true) delay(1000);
  }
  ads.setGain(GAIN_ONE);     // +/-4.096 V full scale, 1 bit = 0.125 mV
}

void loop() {
  // 1) bits -> volts
  float vSoil = ads.computeVolts(ads.readADC_SingleEnded(0));
  float vTmp36 = ads.computeVolts(ads.readADC_SingleEnded(1));

  // 2) volts -> real value
  // moisture: straight line through the two calibration points (more water = lower voltage)
  float moisture = (V_AIR - vSoil) / (V_AIR - V_WATER) * 100.0;
  moisture = constrain(moisture, 0.0, 100.0);
  // temperature: formula from the TMP36 datasheet
  float tempC = (vTmp36 - 0.5) * 100.0;

  Serial.print("Soil: ");
  Serial.print(vSoil, 3);
  Serial.print(" V = ");
  Serial.print(moisture, 0);
  Serial.print(" %   TMP36: ");
  Serial.print(vTmp36, 3);
  Serial.print(" V = ");
  Serial.print(tempC, 1);
  Serial.println(" degrees C");
  delay(1000);
}

Calibrate first: leave the sensor in the air and note the voltage printed, then put it in a glass of water up to the line and note the second one. Write the two values in V_AIR and V_WATER and upload the sketch again.

Other sensors, other formulas

Common mistakes