The electronic dice: your first complete project

1Get the parts ready

• the 16×2 LCD display with I²C module from guide no. 44, already working
• a pushbutton, the breadboard and four more jumper wires

2Build the circuit

The display has the same wires as in guide no. 44, with one difference: now GND has two jobs. Take the board's GND to the − rail of the breadboard, and from there run one wire to the display GND and a short jumper to one leg of the button. The other leg of the button goes to pin 2 (green wire).

3Write and upload the sketch

// Electronic dice: press the button, the numbers spin and stop on one from 1 to 6.
#include <Wire.h>
#include <hd44780.h>
#include <hd44780ioClass/hd44780_I2Cexp.h>

hd44780_I2Cexp lcd;
const int BUTTON = 2;        // with the ESP32 write 27

void setup() {
  pinMode(BUTTON, INPUT_PULLUP);
  randomSeed(analogRead(A0));          // A0 left free: a different "noise" at every power-up
  lcd.begin(16, 2);
  lcd.print("Electronic dice");
  lcd.setCursor(0, 1);
  lcd.print("Press the button");
}

void loop() {
  if (digitalRead(BUTTON) == LOW) {    // you pressed it
    int number = 1;
    for (int roll = 0; roll < 15; roll++) {   // 15 numbers, slower and slower
      number = random(1, 7);                   // from 1 to 6 (7 is excluded)
      lcd.setCursor(0, 1);
      lcd.print("Roll:    ");
      lcd.print(number);
      lcd.print("       ");
      delay(40 + roll * 15);
    }
    while (digitalRead(BUTTON) == LOW) {}      // wait until you let go of the button
  }
}

4How the dice rolls

The for loop repeats 15 times: it picks a number, writes it, waits. The wait is 40 + roll * 15 thousandths of a second: 40 on the first pass, 250 on the last. That is why the numbers slow down like a real dice coming to a stop. The last number written is the result.

5Challenge yourself